【Excel VBA×Selenium】ページの読み込み完了を待つ方法｜document.readyStateを確認する

みなさんこんにちは。

Excel VBAとSeleniumでWebページを操作していると、画面遷移の直後に次の処理が進み、要素を取得できないことがあります。

その対策としてdriver.Wait 3000など固定時間だけ待つ方法もありますが、ページによって読み込み時間が変わるため、待ちすぎたり時間が足りなかったりします。

今回は、JavaScriptのdocument.readyStateを確認し、ページの読み込みが完了するまで待つ方法をご紹介したいと思います。

この記事はこんな人におすすめ

Seleniumで画面遷移後の処理が早すぎてエラーになる人
固定時間のWaitを減らしたい人
document.readyStateをVBAから確認したい人

固定時間だけ待つ場合の問題

例えば、次のように3秒固定で待機すると、ページが1秒で開いても必ず3秒待ちます。反対に、読み込みに5秒かかれば待機時間が不足します。

'========================================
' ページを表示する
'========================================
driver.Get "https://example.com"

'========================================
' 3秒間固定で待機する
'========================================
driver.Wait 3000

document.readyStateを確認する

document.readyStateは、現在のドキュメントの読み込み状態を表します。主な値はloading、interactive、completeです。

SeleniumBasicではExecuteScriptを使って、VBAからJavaScriptを実行できます。

Dim readyState As String

'========================================
' 現在のページ読み込み状態を取得する
'========================================
readyState = CStr( _
    driver.ExecuteScript( _
        "return document.readyState;" _
    ) _
)

Debug.Print readyState

Excel VBA×Seleniumでdocument.readyStateがcompleteになったことを確認した画面

completeになるまで待機する

実際の処理では、readyStateがcompleteになるまで繰り返し確認します。

Dim readyState As String
Dim startTime As Date

'========================================
' 待機開始時刻を記録する
'========================================
startTime = Now

Do

    '========================================
    ' 現在の読み込み状態を取得する
    '========================================
    readyState = CStr( _
        driver.ExecuteScript( _
            "return document.readyState;" _
        ) _
    )

    '========================================
    ' completeならループを終了する
    '========================================
    If readyState = "complete" Then
        Exit Do
    End If

    '========================================
    ' 10秒を超えた場合は処理を終了する
    '========================================
    If DateDiff("s", startTime, Now) >= 10 Then
        MsgBox "ページの読み込みが完了しませんでした。"
        Exit Sub
    End If

    '========================================
    ' 100ミリ秒待ってから再確認する
    '========================================
    driver.Wait 100

Loop

ページの状態に合わせて終了するため、固定時間だけ待つ方法より無駄な待機を減らしやすくなります。