【Excel VBA×Selenium】チェックボックス・ラジオボタンを選択する方法｜選択状態の確認も解説

みなさんこんにちは。

Excel VBAとSeleniumでWebフォームを自動操作する際、チェックボックスやラジオボタンをクリックしたことがある方も多いかと思います。

ただし、チェックボックスはクリックするたびに選択状態が切り替わるため、すでにチェックされている項目を再度クリックすると、逆にチェックが外れてしまいます。

今回は、IsSelectedで選択状態を確認してからClickする方法についてご紹介したいと思います。

この記事はこんな人におすすめ

SeleniumBasicでチェックボックスを操作したい人
ラジオボタンの選択状態を取得したい人
マクロの再実行によるチェック解除を防ぎたい人

今回使用するサンプルページ

今回はSelenium公式のWeb form（操作練習ページ）を使用します。「Default checkbox」と「Default radio」が未選択の状態で表示されていることを確認してください。

Selenium公式Webフォームでチェックボックスとラジオボタンの初期状態を確認した画面

IsSelectedで確認してからClickする

ExcelのVBEで「ツール」→「参照設定」からSelenium Type Libraryを有効にして、次のコードを実行します。

Sub SelectCheckboxAndRadio()

    Dim driver As New Selenium.ChromeDriver
    Dim chk As Selenium.WebElement
    Dim rad As Selenium.WebElement
    Dim i As Long

    'Chromeを起動して操作練習ページを開く
    driver.Start "chrome"
    driver.Get "https://www.selenium.dev/selenium/web/web-form.html"

    '最初は未選択のチェックボックスを取得する
    Set chk = driver.FindElementById("my-check-2")

    '最初は未選択のラジオボタンを取得する
    Set rad = driver.FindElementById("my-radio-2")

    '操作前の選択状態を表示する
    Debug.Print "操作前 checkbox=" & chk.IsSelected
    Debug.Print "操作前 radio=" & rad.IsSelected

    '同じ選択処理を2回実行して結果を比較する
    For i = 1 To 2

        'チェックされていない場合だけクリックする
        '2回目に実行してもチェックは外れない
        If chk.IsSelected = False Then chk.Click

        'ラジオボタンも未選択の場合だけクリックする
        If rad.IsSelected = False Then rad.Click

        '毎回、両方がTrueになっていることを確認する
        Debug.Print i & "回目 checkbox=" & chk.IsSelected
        Debug.Print i & "回目 radio=" & rad.IsSelected

    Next i

    '結果を画面で確認してからChromeを終了する
    MsgBox "両方の選択状態を確認してください。", vbInformation
    driver.Quit

End Sub

ポイントは、IsSelectedがFalseの場合だけClickを実行しているところです。これなら、同じ処理を繰り返してもチェック状態を維持できます。