【Excel VBA×Selenium】ファイルのダウンロード完了を待つ方法｜crdownloadが消えるまで確認する

みなさんこんにちは。

Excel VBAとSeleniumでファイルをダウンロードした直後、ファイルを開けず困ったことはないでしょうか。

今回は、Chromeの一時ファイル.crdownloadを確認し、固定のWaitに頼らず完了を待つ方法をご紹介したいと思います。

ダウンロード中のcrdownloadとは

Chromeはダウンロード中に.crdownloadを作る場合があります。完了すると通常のファイル名になります。小さいファイルでは、一時ファイルを確認できないこともあります。

今回はSelenium公式テストページの「File 1」を使用します。

Selenium公式のファイルダウンロード確認ページでFile 1のリンクを表示した画面

サンプルコード

マクロを記述したブックを保存してから実行してください。参照設定には「Selenium Type Library」が必要です。

Option Explicit

Sub WaitChromeDownload()
    Dim driver As New Selenium.ChromeDriver
    Dim folder As String, target As String
    Dim deadline As Date, finished As Boolean

    '保存済みブックの横に専用フォルダを作る
    If ThisWorkbook.Path = "" Then
        MsgBox "先にブックを保存してください。": Exit Sub
    End If
    folder = ThisWorkbook.Path & "\DownloadTest"
    If Dir(folder, vbDirectory) = "" Then MkDir folder
    target = folder & "\file_1.txt"

    '古いファイルによる完了の誤判定を防ぐ
    If Dir(target) <> "" Then Kill target
    If Dir(folder & "\*.crdownload") <> "" Then
        MsgBox "一時ファイルが残っています。": Exit Sub
    End If

    On Error GoTo ErrProc
    'Chrome起動前に保存先を指定する
    driver.SetPreference "download.default_directory", folder
    driver.SetPreference "download.prompt_for_download", False
    driver.SetPreference "download.directory_upgrade", True
    driver.Start "chrome"

    'Selenium公式ページからダウンロード開始
    driver.Get "https://www.selenium.dev/selenium/web/downloads/download.html"
    driver.FindElementById("file-1").Click

    '30秒を上限に、完成ファイルと一時ファイルを確認
    deadline = DateAdd("s", 30, Now)
    Do
        If Dir(target) <> "" And _
           Dir(folder & "\*.crdownload") = "" Then
            finished = True
            Exit Do
        End If
        If Now >= deadline Then Exit Do
        driver.Wait 200
        DoEvents
    Loop

    '成功またはタイムアウトを通知する
    If finished Then
        MsgBox "ダウンロード完了：" & target
    Else
        MsgBox "30秒経過：完了を確認できませんでした。"
    End If

ExitProc:
    On Error Resume Next
    driver.Quit
    Exit Sub
ErrProc:
    MsgBox "エラー：" & Err.Description
    Resume ExitProc
End Sub