【Excel VBA×Selenium】href・src・data属性の値を取得する方法｜Attributeの使い方

<!DOCTYPE html>
<html lang="ja"><meta charset="UTF-8">
<h1>属性値取得テスト</h1>
<a id="productLink" href="https://www.selenium.dev/" data-product-id="A001">商品ページ</a>
<img id="productImage" src="https://www.selenium.dev/images/selenium_logo_square_green.png" width="80" alt="Seleniumロゴ">
</html>

Option Explicit
Sub GetAttributeSample()
    Dim driver As New Selenium.ChromeDriver
    Dim linkEl As Selenium.WebElement
    Dim imgEl As Selenium.WebElement
    Dim v As Variant
    Dim htmlPath As String

    'テスト用HTMLの保存場所を確認
    htmlPath = ThisWorkbook.Path & "\attribute-test.html"
    If ThisWorkbook.Path = "" Or Dir(htmlPath) = "" Then
        MsgBox "ブックとHTMLを同じ場所に保存してください。"
        Exit Sub
    End If
    driver.Start "chrome"
    driver.Get "file:///" & Replace(htmlPath, "\", "/")

    '見つからない場合はNothingとして判定
    Set linkEl = driver.FindElementById("productLink", 3000, False)
    Set imgEl = driver.FindElementById("productImage", 3000, False)
    If linkEl Is Nothing Or imgEl Is Nothing Then
        MsgBox "対象要素がありません。"
    Else
        '表示文字とHTML属性を取得
        Debug.Print "Text：" & linkEl.Text
        Debug.Print "href：" & linkEl.Attribute("href")
        Debug.Print "src：" & imgEl.Attribute("src")
        Debug.Print "data-product-id：" & linkEl.Attribute("data-product-id")

        '属性がなければNullや空値が返る場合がある
        v = linkEl.Attribute("data-missing")
        If IsNull(v) Or IsEmpty(v) Then
            Debug.Print "data-missing：値なし"
        ElseIf CStr(v) = "" Then
            Debug.Print "data-missing：値なし"
        End If
    End If
    driver.Quit
End Sub

Text：商品ページ
href：https://www.selenium.dev/
src：https://www.selenium.dev/images/selenium_logo_square_green.png
data-product-id：A001
data-missing：値なし