【Excel VBA×Selenium】要素が表示されるまで待つ方法|固定Sleepを使わずに待機する

みなさんこんにちは。

Excel VBAとSeleniumで、要素が表示される前に次の処理が進んでエラーになった経験はないでしょうか。

今回は、固定Sleepを使わず、WaitDisplayedで要素が表示されるまで待機する方法についてご紹介したいと思います。

固定時間だけ待機する場合の問題

driver.Wait 3000のような固定待機は、表示が早いと時間を無駄にし、遅いと待機不足になります。

今回使用するテストHTML

次をwait-displayed-test.htmlとしてExcelと同じフォルダへ保存します。ボタンを押すと2秒後に表示されます。

<!DOCTYPE html>
<meta charset="UTF-8">
<button id="startButton" onclick="setTimeout(() => document.getElementById('targetMessage').style.display='block', 2000)">表示を開始</button>
<p id="targetMessage" style="display:none">表示されました(待機成功)</p>
Excel VBAとSeleniumBasicのWaitDisplayedで要素の表示を待機する前のテストページ

WaitDisplayedで表示されるまで待つ

Excelの標準モジュールにVBAを記述します。参照設定で「Selenium Type Library」を有効にしておいてください。

Option Explicit

Sub WaitUntilDisplayed()

    Dim driver As Selenium.ChromeDriver
    Dim target As Selenium.WebElement
    Dim htmlPath As String

    On Error GoTo ErrHandler

    ' Excelと同じフォルダのHTMLを指定
    htmlPath = ThisWorkbook.Path & "\wait-displayed-test.html"
    If Dir(htmlPath) = "" Then
        MsgBox "テストHTMLが見つかりません。"
        Exit Sub
    End If

    ' Chromeを起動する
    Set driver = New Selenium.ChromeDriver
    driver.Start "chrome"
    driver.Get "file:///" & Replace(htmlPath, "\", "/")

    ' まだ非表示の要素を取得する
    Set target = driver.FindElementById("targetMessage", 3000, False)
    If target Is Nothing Then GoTo CleanUp
    Debug.Print "待機前:" & target.IsDisplayed

    ' 2秒後に表示させ、最大5秒待つ
    driver.FindElementById("startButton").Click
    target.WaitDisplayed True, 5000

    Debug.Print "待機後:" & target.IsDisplayed
    Debug.Print "取得結果:" & target.Text
    MsgBox "表示成功。撮影後OKを押してください。"

CleanUp:
    On Error Resume Next
    If Not driver Is Nothing Then driver.Quit
    Exit Sub

ErrHandler:
    MsgBox "待機失敗:" & Err.Description
    Resume CleanUp

End Sub
Excel VBAとSeleniumBasicでFindElementByIdとWaitDisplayedを使用して要素の表示を待機するコード

コードのポイントとタイムアウト

FindElementByIdは要素を探します。今回は非表示でもDOM内にあるので取得でき、存在しなければNothingとなります。

target.WaitDisplayed True, 5000は最大5秒間、表示状態になるまで待機する処理です。2秒後に表示された時点で次へ進み、5秒を超えても表示されなければタイムアウトのエラーになります。引数の単位はミリ秒です。

実行結果を確認する

WaitUntilDisplayedを実行すると約2秒後に表示され、イミディエイトウィンドウに次の結果が出ます。

待機前:False
待機後:True
取得結果:表示されました(待機成功)
Excel VBAとSeleniumBasicのWaitDisplayedで要素の表示を待機し、表示成功メッセージが表示されたテストページ

使うときの注意点

WaitDisplayedは取得済みの要素の表示を待ちます。要素自体が後から生成される場合は、先にFindElementByIdで出現を待ってください。

待機中に要素が差し替えられる場合は再取得が必要です。

も参考にしてください。

最後に

いかがでしたでしょうか。今回は、WaitDisplayedで要素が表示されるまで待機する方法をご紹介しました。固定時間ではなく表示状態を確認することで、処理を安定させやすくなります。少しでも参考になれば幸いです。

開発依頼について

ココナラでWebスクレイピング開発サービスを出品しております。

自分で開発をしようと思ったけど、VBAでのネット記事が少なく困っている方も多いかと思います。

そんな方はいつでもお気軽にご相談ください。

また、本ブログからご依頼いただいた方については割引特典がございますので、

ご不明点と合わせてメッセージをいただけると幸いです。

業務の流れをまるごと自動化します Excel・Web・Teams・SaaSで業務全体を自動化

Webスクレイピング以外にもWebアプリの開発サービスも出品しております。

こちらについても、本ブログからご依頼いただいた方については割引特典がございますので、

お気軽にご相談ください。

スモールスケールのWebアプリ開発します 先ずはスモールスケールのWebアプリから始めませんか?

ご興味がある方はこちら!!

コメントを残す

メールアドレスが公開されることはありません。 ※ が付いている欄は必須項目です

CAPTCHA